Obsah

# Příkaz Line Input#

Načte řádek ze sekvenčního souboru do proměnné.

### Syntaxe:

    Line Input #fileNum, variable

### Parametry:

fileNum: Číslo souboru, který obsahuje data, jež chcete načíst. Před použitím klíčového slova INPUT musí být soubor otevřen příkazem Open.

variable: Název proměnné, do které se uloží výsledek.

Příkazem Line Input# je možné načítat řetězce z otevřeného souboru do proměnné. Řetězcové proměnné se načítají řádek po řádku, až do prvního znaku návrat vozíku (Asc=13) nebo nový řádek (Asc=10). Znaky konce řádku nejsou zahrnuty ve výsledném řetězci.

### Příklad:

      Sub ExampleWorkWithAFile
          Dim iNumber As Integer
          Dim sLine As String
          Dim aFile As String
          Dim sMsg As String
          aFile = "C:\Users\ThisUser\data.txt"
          iNumber = Freefile
          Open aFile For Output As #iNumber
          Print #iNumber, "Toto je řádek textu"
          Print #iNumber, "Toto je další řádek textu"
          Close #iNumber
          iNumber = Freefile
          Open aFile For Input As iNumber
          While Not eof(iNumber)
              Line Input #iNumber, sLine
              If sLine <>"" Then
                  sMsg = sMsg & sLine & chr(13)
              End If
          Wend
          Close #iNumber
          MsgBox sMsg
      End Sub

      Sub ExampleWorkWithAFile
          Dim iNumber As Integer
          Dim sLine As String
          Dim aFile As String
          Dim sMsg As String
          aFile = "~/data.txt"
          iNumber = Freefile
          Open aFile For Output As #iNumber
          Print #iNumber, "Toto je řádek textu"
          Print #iNumber, "Toto je další řádek textu"
          Close #iNumber
          iNumber = Freefile
          Open aFile For Input As iNumber
          While Not eof(iNumber)
              Line Input #iNumber, sLine
              If sLine <>"" Then
                  sMsg = sMsg & sLine & chr(13)
              End If
          Wend
          Close #iNumber
          MsgBox sMsg
      End Sub

Související témata

Příkaz Open

Příkaz Print#

Příkaz Write#